Fade to black

Blitz3D Forums/Blitz3D Beginners Area/Fade to black

The forum is locked. These are the original blitzbasic.com forums, kept so they can still be read. No new topics, replies or edits can be made here. To join in, head over to the Blitz3D+ forums.

Rob Farley
 #1
Open in online IDE
Graphics3D 640,480,32,2

camera = CreateCamera()
FadeEntities = CreatePivot()
NonFadeEntities = CreatePivot()

fadecube = CreateCube()
EntityColor fadecube,0,0,0
FlipMesh fadecube
EntityAlpha fadecube,0

Light=CreateLight()


For n=1 To 20
	cube = CreateCube(NonFadeEntities)
	PositionEntity cube,Rnd(-5,5),Rnd(-5,5),Rnd(0,20)
	ScaleEntity cube,Rnd(.2,1),Rnd(.2,1),Rnd(.2,1)
	RotateEntity cube,Rnd(360),Rnd(360),Rnd(360)
	EntityColor cube,Rand(255),Rand(255),Rand(255)
Next

For n=1 To 20
	cube = CreateCube(FadeEntities)
	PositionEntity cube,Rnd(-5,5),Rnd(-5,5),Rnd(0,20)
	ScaleEntity cube,Rnd(.2,1),Rnd(.2,1),Rnd(.2,1)
	RotateEntity cube,Rnd(360),Rnd(360),Rnd(360)
	EntityColor cube,Rand(255),Rand(255),Rand(255)
Next


a# = 0
Repeat
	EntityAlpha fadecube,Abs(Sin(a))
	a = a + .5
	
	CameraClsMode camera,True,True
	HideEntity NonFadeEntities
	ShowEntity FadeEntities
	ShowEntity fadecube
	RenderWorld
	CameraClsMode camera,False,True
	ShowEntity NonFadeEntities
	HideEntity FadeEntities
	HideEntity fadecube
	RenderWorld 
	Flip
Until KeyHit(1)